Subversion, Git ディレクトリをミラーリング、同期しコミットする方法

同期したいディレクトリにミラーリング処理を実行する

Windowsでミラーリングを行うには、robocopyコマンドがあります。
オプションで、ミラーリングだけでなくリトライ回数を指定したり、除外ディレクトリ指定等が出来ます。

robocopy %SRC_PATH% %DEST_PATH% /MIR /XD .git /NP R:1

コマンドの説明は割愛します。

ステータスを確認し、追加削除処理を行う

svn status
?     unmanaged.txt
!     lost.txt
A       add-file.txt

git status -s
A  add-file.txt
 D deleted.txt
?? unmanaged.txt

Subversion - bat

@echo off
rem .svn ディレクトリを除外しなければいけない事に注意
robocopy %SRC_PATH% %DEST_PATH% /MIR /XD .svn /NP R:3
if errorlevel 8 goto error

pushd %DEST_PATH%
for /F "usebackq tokens=1,2" %%i IN (`svn status`) do (
    if %%i==? (
        rem 管理外ファイルという事は追加されたファイル
        svn add %%j
    ) else if %%i==! (
        rem 紛失しているという事は削除されたファイル
        svn delete %%j
    )
)

svn commit -m "ミラーリング"
popd
exit /b 0

:error
echo error robocopyに失敗
exit /b 1

Git - bat

@echo off
rem .git ディレクトリを除外しなければいけない事に注意
robocopy %SRC_PATH% %DEST% /MIR /XD .git /NP R:3
if errorlevel 8 goto error

pushd %DEST_PATH%
for /F "usebackq tokens=1,2" %%i IN (`git status -s`) do (
    if %%i==?? (
        rem 管理外ファイルという事は追加されたファイルの可能性
        git add  %%j
    ) else if %%i==D (
        rem 削除状態をステージングへ
        git add  %%j
    )
)

git commit -m "ミラーリング"
git push origin master
popd
exit /b 0

:error
echo error robocopyに失敗
exit /b 1